home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / C64 / F-French / (c)f1.d64 / jeu de yum (.txt) < prev    next >
Commodore BASIC  |  2007-02-04  |  5KB  |  157 lines
  1. 1 GOSUB7000
  2. 2 POKE53281,10
  3. 3 POKE53280,5
  4. 10 PRINT"[147]JEU DE YUM[146]"
  5. 20 PRINT"=========="
  6. 30 INPUT"NOMBRE DE JOUEURS (1 A 11) ";M
  7. 31 IFM<1ORM>11THENRUN
  8. 40 FORI=1TOM:PRINT"NOM DU JOUEUR"I;:INPUTM$(I)
  9. 50 IFLEN(M$(I))<6THENM$(I)=M$(I)+" ":GOTO50
  10. 60 NEXT
  11. 140 N=3:A$(1)="MONTEE":A$(2)="DESCENTE":A$(3)="LIBRE"
  12. 200 DIMZ$(12),C%(M,3,12),T%(M,3,12),JJ(36),G(12),X$(6),J(12),C$(3,12)
  13. 202 DIMCS(3),CX(3),S$(3),CZ(M,3),CT(3),W$(3),U$(3),LL(M),KK(M)
  14. 210 FORJ=1TO12:READZ$(J):NEXT
  15. 220 DATA"1","2","3","4","5","6"
  16. 222 DATAFULL  ,CARRE ,QUINTE,YUM   ,MAXI  ,MINI  ,
  17. 240 X$(1)="   [157][157][157] [209] [157][157][157]   ":X$(2)="[209]  [157][157][157]   [157][157][157]  [209]"
  18. 245 X$(3)="[209]  [157][157][157] [209] [157][157][157]  [209]":X$(6)="[209][209][209][157][157][157]   [157][157][157][209][209][209]"
  19. 250 X$(4)="[209] [209][157][157][157]   [157][157][157][209] [209]":X$(5)="[209] [209][157][157][157] [209] [157][157][157][209] [209]"
  20. 255 FORA=1TOM:LL(A)=12:KK(A)=1:NEXT
  21. 260 FORA=1TOM:FORJ=1TO12:FORI=1TON:C%(M,I,J)=0:T%(M,I,J)=0:NEXT:NEXT:NEXT
  22. 261 FORJJ=1TO36
  23. 262 FORA=1TOM
  24. 270 KM=5:L=5
  25. 275 FORH=1TO5:F(H)=H:NEXTH
  26. 280 FORK=1TO3:PRINT"[147]JOUEUR "M$(A):PRINT"COUP NUMERO"JJSPC(10);
  27. 285 PRINT"LANCER NUMERO"K""
  28. 287 FORW=1TO20:IFW>1THENPRINT"[145][145]"
  29. 288 T%=PEEK(143)
  30. 290 FORH=1TOL:B(F(H))=INT(6*RND(T%+H)+1):NEXTH
  31. 300 FORD=1TOKM:PRINT""X$(B(D))"[145][145]";:NEXTD:PRINT"":NEXTW
  32. 305 GOSUB2900
  33. 310 IFK=3THEN350
  34. 320 PRINT"COMBIEN DE DES REJOUEZ-VOUS?"
  35. 321 GETL$:IFL$<>"0"ANDL$<>"1"ANDL$<>"2"ANDL$<>"3"ANDL$<>"4"ANDL$<>"5"THEN321
  36. 322 IFL$="0"THEN350
  37. 323 IFL$="5"THEN340
  38. 330 L=VAL(L$):PRINT"QUEL(S) DE(S) ?":FORE=1TOL
  39. 331 GETF$
  40. 332 IFF$<>"1"ANDF$<>"2"ANDF$<>"3"ANDF$<>"4"ANDF$<>"5"THEN331
  41. 334 F(E)=VAL(F$)
  42. 335 NEXTE
  43. 340 NEXTK
  44. 350 PRINT"SUR QUEL TABLEAU JOUEZ-VOUS(M,D,L)?"
  45. 351 GETWZ$
  46. 352 IFWZ$<>"L"ANDWZ$<>"M"ANDWZ$<>"D"THEN351
  47. 355 IFWZ$="L"THEN400
  48. 360 IFWZ$="M"THEN364
  49. 362 IFWZ$="D"THEN369
  50. 363 PRINT"ERREUR":GOTO350
  51. 364 II=1:IFLL(A)<1GOTO363
  52. 365 Y$=Z$(LL(A)):IFLL(A)<7THENY$=MID$(Y$,4,1)
  53. 366 LL(A)=LL(A)-1:GOTO410
  54. 369 II=2:IFKK(A)>12THEN363
  55. 370 Y$=Z$(KK(A)):IFKK(A)<7THENY$=MID$(Y$,4,1)
  56. 372 KK(A)=KK(A)+1:GOTO410
  57. 400 II=3:PRINT"QUELLE COMBINAISON CHOISISSEZ-VOUS";:INPUTY$
  58. 410 FORG=1TO6:IFY$=MID$(Z$(G),4,1)THEN440
  59. 415 NEXT
  60. 420 FORG=7TO12:IFLEFT$(Y$,3)=LEFT$(Z$(G),3)THEN440
  61. 425 NEXT
  62. 430 PRINT"COMBINAISON INCONNUE":GOTO400
  63. 440 IFT%(A,II,G)=1THENPRINT"COMBINAISON DEJA CHOISIE":GOTO350
  64. 450 I=II:J=G:T%(A,I,J)=1:FORW=1TO5:R(W)=B(W):NEXT
  65. 460 FORV=1TO5
  66. 470 JM=1:MM=R(JM)
  67. 480 FORW=2TO5:IFR(W)<=MMTHEN500
  68. 490 JM=W:MM=R(W)
  69. 500 NEXTW
  70. 510 PO(V)=JM:R(JM)=-1
  71. 520 NEXTV
  72. 540 ONJGOSUB3300,3300,3300,3300,3300,3300,3410,3500,3610,3710,3810,3910,
  73. 580 NEXTA
  74. 585 NEXTJJ
  75. 599 FORA=1TOM:GOSUB3000
  76. 600 VV=CZ(A,1)+CZ(A,2)+CZ(A,3):SM=1032:MX=INT(100*VV/SM+.5)
  77. 610 PRINT"SCORE:"VV"MAXI.:"SM"TAUX:"STR$(MX)+"%[146]":GOSUB5000
  78. 615 NEXT
  79. 618 PRINT"VOULEZ-VOUS JOUER UNE AUTRE PARTIE ?"
  80. 619 GETA$:IFA$<>"N"ANDA$<>"O"THEN619
  81. 620 IFA$="O"THEN255
  82. 630 END
  83. 2800 PRINT"[147]JOUEUR "M$(A):PRINT"COUP NUMERO"JJSPC(10);
  84. 2810 PRINT"LANCER NUMERO"K""
  85. 2820 FORD=1TOKM:PRINT""X$(B(D))"[145][145]";:NEXTD
  86. 2900 PRINT:PRINT"VOULEZ-VOUS VOIR LA MARQUE (O/N)?"
  87. 2902 GETQ$
  88. 2905 IFQ$<>"O"ANDQ$<>"N"THEN2902
  89. 2910 IFQ$="N"THENRETURN
  90. 3000 PRINT"[147][207][183][183][183][183][183][183][208][183][183][183][183][183][183][183][208][183][183][183][183][183][183][183][183][207][183][183][183][183][183][183][208]"
  91. 3005 MM$(A)=""+LEFT$(M$(A),6)+"[146]"
  92. 3010 PRINT"[180]"MM$(A)"[170] MONTEE[170]DESCENTE[180]LIBRE [170]"
  93. 3020 PRINT"[204][175][175][175][175][175][175][186][175][175][175][175][175][175][175][186][175][175][175][175][175][175][175][175][204][175][175][175][175][175][175][186]"
  94. 3032 FORG=1TO6
  95. 3040 PRINT"[180]"Z$(G)"[167]";:FORI=1TON:OQ=C%(A,I,G):GOSUB6000:NEXTI:PRINT""
  96. 3045 NEXTG
  97. 3046 FORH=1TO32:PRINT"[183]";:NEXT:PRINT""
  98. 3050 FORI=1TON:CS(I)=0:FORG=1TO6:CS(I)=CS(I)+C%(A,I,G):NEXTG
  99. 3056 NEXTI
  100. 3057 G=13
  101. 3060 PRINT"[180]TOTAL1[167]";:FORI=1TON:OQ=CS(I):GOSUB6000:NEXTI:PRINT""
  102. 3065 FORI=1TON:T(I)=0:IFCS(I)>60THENT(I)=30
  103. 3068 NEXTI
  104. 3070 PRINT"[180]BONUS [167]";:FORI=1TON:OQ=T(I):GOSUB6000:NEXT:PRINT""
  105. 3075 FORI=1TON:CT(I)=CS(I)+T(I)
  106. 3078 NEXTI
  107. 3080 PRINT"[180]TOTAL2[167]";:FORI=1TON:OQ=CT(I):GOSUB6000:NEXTI:PRINT""
  108. 3090 FORH=1TO32:PRINT"[183]";:NEXT:PRINT""
  109. 3100 FORG=7TO12
  110. 3120 PRINT"[180]"Z$(G)"[170]";:FORI=1TON:OQ=C%(A,I,G):GOSUB6000:NEXTI:PRINT""
  111. 3130 NEXTG
  112. 3140 FORH=1TO32:PRINT"[183]";:NEXT:PRINT""
  113. 3150 FORI=1TON
  114. 3155 CX(I)=0
  115. 3160 FORG=7TO12:CX(I)=CX(I)+C%(A,I,G):NEXTG
  116. 3170 CZ(A,I)=CT(I)+CX(I)
  117. 3178 NEXTI
  118. 3180 PRINT"[180]TOTAL3[167]";:FORI=1TON:OQ=CZ(A,I):GOSUB6000:NEXTI:PRINT""
  119. 3190 PRINT"[204][175][175][175][175][175][175][186][175][175][175][175][175][175][175][186][175][175][175][175][175][175][175][186][175][175][175][175][175][175][175][186]":IFJJ<36THENGOSUB5000
  120. 3195 IFJJ<37THENGOSUB2800
  121. 3200 RETURN
  122. 3300 FORV=1TO5:IFB(PO(V))=JTHENC%(A,I,J)=C%(A,I,J)+B(PO(V))
  123. 3315 NEXTV
  124. 3320 RETURN
  125. 3410 IFB(PO(1))=B(PO(2))ANDB(PO(2))=B(PO(3))ANDB(PO(4))=B(PO(5))THENC%(A,I,J)=30
  126. 3420 IFB(PO(1))=B(PO(2))ANDB(PO(3))=B(PO(4))ANDB(PO(4))=B(PO(5))THENC%(A,I,J)=30
  127. 3430 RETURN
  128. 3500 FORV=1TO5
  129. 3510 IFB(PO(1))=B(PO(2))ANDB(PO(2))=B(PO(3))ANDB(PO(3))=B(PO(4))THENC%(A,I,J)=30
  130. 3520 IFB(PO(2))=B(PO(3))ANDB(PO(3))=B(PO(4))ANDB(PO(4))=B(PO(5))THENC%(A,I,J)=30
  131. 3525 NEXTV
  132. 3530 RETURN
  133. 3610 FORV=1TO4:IFB(PO(V+1))=B(PO(V))-1THENNEXT
  134. 3615 IFV=5THENC%(A,I,J)=40
  135. 3620 RETURN
  136. 3710 FORV=1TO4:IFB(PO(V+1))=B(PO(V))THEN NEXTV:IFV=5THENC%(A,I,J)=50
  137. 3720 RETURN
  138. 3810 FORV=1TO5:C%(A,I,J)=C%(A,I,J)+B(PO(V)):NEXT
  139. 3820 IFT%(A,I,12)=1ANDC%(A,I,12)>=C%(A,I,J)THENC%(A,I,J)=0
  140. 3830 RETURN
  141. 3910 FORV=1TO5:C%(A,I,J)=C%(A,I,J)+B(PO(V)):NEXT
  142. 3920 IFT%(A,I,11)=1ANDC%(A,I,11)<=C%(A,I,J)THENC%(A,I,J)=0
  143. 3930 RETURN
  144. 5000 GETA$:IFA$=""THEN5000
  145. 5010 RETURN
  146. 6000 IFG=13ANDOQ=0THENPRINT"       [167]";:GOTO6020
  147. 6002 IFG=13THEN6010
  148. 6005 IFT%(A,I,G)=0THENPRINT"       [167]";:GOTO6020
  149. 6010 PRINTSPC(5-LEN(STR$(OQ)))OQSPC(1)"[167]";
  150. 6020 RETURN
  151. 7000 PRINT"[147]"
  152. 7070 POKE53280,2:POKE53281,11
  153. 7080 PRINT" YUM "
  154. 7090 PRINT"[144]PRESSEZ UNE TOUCHE"
  155. 8000 GETJ$:IFJ$=""THEN8000
  156. 8010 RETURN
  157.